/* BVerfG Chang
170829
*/


clear
set more off
cd "/Users/engel/Documents/word/Manuskript/Governance/BVerfG/Data/" 
use "./BVerfG2011_120106.dta"


***** globals

global drop _all
global ser proc chamber oral relmaj brf_sol length black press alt aim
global serch proc brf_sol length press alt aim
global bench left joint reltenure relsum relprof relfemale relage
global case targ_tstat targ_supr represented repr_spec brief_tot top_bus top_soc top_fam top_civ top_inst top_pub top_tax



***** individual indicators for taking a case seriously

foreach var of varlist $ser {
	tab `var'
	tab `var' if cc
	tab `var' if cc & chamber
	}
	
su length	

**** correlation structure

sem (<- $ser), standardized

	
***** latent variable: all cc

factor $ser
factor $ser if cc
screeplot, yline(1)
factor $ser if cc, factors(1)
predict fcc
hist fcc, percent xtitle("seriousness score") ytitle("percentage")

**** robustness

rotate


***** bench characteristics

foreach var of varlist $bench {
	su `var'
	su `var' if cc
	su `var' if cc & chamber
	}

**** correlation structure

sem (<- $bench), standardized
	
	
**** univariate analysis	
	
foreach var of varlist $bench {
	reg fcc `var' if cc
	reg fcc `var' $case if cc
	}

**** chambers only

foreach var of varlist $bench {
	reg fcc `var' if cc & chamber
	reg fcc `var' $case if cc & chamber
	}
	
**** multivariate	
	
reg fcc $bench if cc
reg fcc $bench $case if cc

reg fcc $bench if cc & chamber
reg fcc $bench $case if cc & chamber


**** SEM

sem (ernst -> $ser) ///
	(ernst <- $bench) ///
	if cc, latent(ernst) nocapslatent
	
sem (ernst -> $ser) ///
	(ernst <- $bench $case) ///
	if cc, latent(ernst) nocapslatent

sem (ernst -> $serch) ///
	(ernst <- $bench) ///
	if cc & chamber, latent(ernst) nocapslatent
	
sem (ernst -> $serch) ///
	(ernst <- $bench $case) ///
	if cc & chamber, latent(ernst) nocapslatent